NSIS installer script

Discuss development issues and submit patches here
Post Reply
MrD
Posts: 1
Joined: Sun Jan 15, 2012 12:33 pm

NSIS installer script

Post by MrD »

Here's a NSIS installer script -- works for me (tested on Vista x32 &
Win7 x64). Use it if you wish.

Make a directory with the contents:

Explorer++.nsi
License.txt
explorer++_1.3.4_x64.zip
explorer++_1.3.4_x86.zip

Change line #2 of Explorer++.nsi when the version (and zip file names) change.

Use NSIS to compile the script.

See:
http://nsis.sourceforge.net/Main_Page
http://nsis.sourceforge.net/ZipDLL_plug-in

You may want to tweak it. Since the uninstall uses "rmdir /r" on the install
directory, a malicious (or ignorant) user could install it into C:\Windows and it's sort of
obvious what will happen on an uninstall. Since I don't do that, this script
works for me.

Code: Select all

!define PRODUCT_NAME "Explorer++"
!define PRODUCT_VERSION "1.3.4"
!define PRODUCT_PUBLISHER "Explorer++"
!define PRODUCT_WEB_SITE "http://www.explorerplusplus.com/"
!define PRODUCT_DIR_REGKEY "Software\Microsoft\Windows\CurrentVersion\App Paths\${PRODUCT_NAME}"
!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
!define PRODUCT_UNINST_ROOT_KEY "HKLM"
!define PRODUCT_STARTMENU_REGVAL "NSIS:StartMenuDir"

!include "MUI.nsh"
!include "zipdll.nsh"
!include "WinVer.nsh"
!include "x64.nsh"

var ICONS_GROUP
!define MUI_ABORTWARNING
!define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\modern-install.ico"
!define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall.ico"
!define MUI_STARTMENUPAGE_NODISABLE
!define MUI_STARTMENUPAGE_DEFAULTFOLDER "Explorer++"
!define MUI_STARTMENUPAGE_REGISTRY_ROOT "${PRODUCT_UNINST_ROOT_KEY}"
!define MUI_STARTMENUPAGE_REGISTRY_KEY "${PRODUCT_UNINST_KEY}"
!define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "${PRODUCT_STARTMENU_REGVAL}"
!define MUI_FINISHPAGE_RUN "$INSTDIR\Explorer++.exe"
!define MUI_FINISHPAGE_NOAUTOCLOSE
!define MUI_UNFINISHPAGE_NOAUTOCLOSE 

!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "License.txt"
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_STARTMENU Application $ICONS_GROUP
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"

Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
OutFile "SetupExplorer++.exe"
InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" ""
ShowInstDetails show
ShowUnInstDetails show

Function .OnInit
  ${If} ${RunningX64}
    StrCpy $INSTDIR "$PROGRAMFILES64\Explorer++"
  ${Else}
    StrCpy $INSTDIR "$PROGRAMFILES\Explorer++"
  ${EndIf}
FunctionEnd

Section "MainSection" SEC01
SetShellVarContext all
  SetOutPath "$INSTDIR"
  SetOverwrite ifnewer

  ${If} ${IsWinXP}
    ${If} ${RunningX64}
      File /oname=Explorer++.zip "explorer++_${PRODUCT_VERSION}_x64.zip"
    ${Else}
      File /oname=Explorer++.zip "explorer++_${PRODUCT_VERSION}_x86.zip"
    ${EndIf}
  ${ElseIf} ${IsWinVista}
    ${If} ${RunningX64}
      File /oname=Explorer++.zip "explorer++_${PRODUCT_VERSION}_x64.zip"
    ${Else}
      File /oname=Explorer++.zip "explorer++_${PRODUCT_VERSION}_x86.zip"
    ${EndIf}
  ${ElseIf} ${IsWin7}
    ${If} ${RunningX64}
      File /oname=Explorer++.zip "explorer++_${PRODUCT_VERSION}_x64.zip"
    ${Else}
      File /oname=Explorer++.zip "explorer++_${PRODUCT_VERSION}_x86.zip"
    ${EndIf}
  ${ElseIf} ${RunningX64}
      File /oname=Explorer++.zip "explorer++_${PRODUCT_VERSION}_x64.zip"
    ${Else}
      File /oname=Explorer++.zip "explorer++_${PRODUCT_VERSION}_x86.zip"
  ${EndIf}

!insertmacro ZIPDLL_EXTRACT "$INSTDIR\Explorer++.zip" "$INSTDIR" "<ALL>"
  Delete /REBOOTOK "$INSTDIR\Explorer++.zip"

  !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
  CreateDirectory "$SMPROGRAMS\$ICONS_GROUP"
  CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\Explorer++.lnk" "$INSTDIR\Explorer++.exe"
  WriteIniStr    "$SMPROGRAMS\$ICONS_GROUP\Website.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
  CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\Uninstall.lnk" "$INSTDIR\uninst.exe"
  !insertmacro MUI_STARTMENU_WRITE_END

  WriteUninstaller "$INSTDIR\uninst.exe"
  WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\Explorer++.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\Explorer++.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
SectionEnd


Function un.onInit
  MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Are you sure you want to completely remove $(^Name) and all of its components?" IDYES +2
  Abort
FunctionEnd

Section Uninstall
SetShellVarContext all
  !insertmacro MUI_STARTMENU_GETFOLDER "Application" $ICONS_GROUP
  RMDir /r /REBOOTOK "$INSTDIR"
  RMDir /r /REBOOTOK "$SMPROGRAMS\$ICONS_GROUP"

  DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
  DeleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"
SectionEnd

Section un.removeConfig
  MessageBox MB_YESNO|MB_DEFBUTTON1 "Permanently remove Explorer++ configuration settings?" IDNO no
    DeleteRegKey HKCU "Software\Explorer++"
no:
SectionEnd

Function un.onUninstSuccess
  HideWindow
  MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) was successfully removed from your computer."
FunctionEnd
Post Reply